RETURN expression;

RETURN 带有一个表达式将会终止该函数并将expression 的值返回给调用者。此形式用于不返回集合的 PL/pgSQL 函数。

对于返回标量类型的函数，表达式的结果会自动转换为函数的返回类型，如对赋值所述。但是，若要返回复合（行）的值，您必须编写一个表达式，用以准确提供所请求的列集。这可能需要使用显式转换。

如果您使用输出参数声明了该函数，只需编写 RETURN，后面不带任何表达式。当前输出参数变量的值将被返回。

如果您声明该函数返回 void，则可以使用 RETURN 语句提前退出函数；但在 RETURN 后不要编写表达式。

函数的返回值不能留空。如果控制到达函数的顶级块末尾，而没有遇到 RETURN 语句，将会发生运行时错误。然而，此限制不适用于具有输出参数的函数和返回 void 的函数。在这些情况下，如果顶级块完成，将会自动执行 RETURN 语句。

一些示例

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

当声明一个 PL/pgSQL 函数以返回 SETOF sometype 时，要遵循的步骤略有不同。在这种情况下，要返回的各个项目由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然后使用一个没有任何参数的最终 RETURN 命令来表明该函数已完成执行。RETURN NEXT 可以与标量和复合数据类型一起使用；对于一个复合结果类型，将返回一个包含结果的完整 “表”。RETURN QUERY 将执行查询的结果附加到该函数的结果集。一个单独的设置返回函数中可以自由地混用 RETURN NEXT 和 RETURN QUERY，在这种情况下它们的结果将被连接在一起。

RETURN NEXT 和 RETURN QUERY 实际上并未从此函数返回 — 它们只是将零行或多行附加到该函数的结果集中。然后执行将继续执行 PL/pgSQL 函数中的下一条语句。随着连续执行 RETURN NEXT 或 RETURN QUERY 命令，结果集将被构建起来。一个最终的 RETURN（不应有任何参数）会导致控制退出该函数（或者您只需让控制到达函数的末尾）。

RETURN QUERY 有一个变体 RETURN QUERY EXECUTE，它以动态方式指定要执行的查询。参数表达式可以通过 USING 插入到计算查询字符串中，就像在 EXECUTE 命令中一样。

如果您使用输出参数声明了该函数，只需编写一个没有任何表达式的 RETURN NEXT。在每次执行时，输出参数变量的当前值将被保存以最终作为结果行返回。请注意，当有多个输出参数时，您必须将该函数声明为返回 SETOF record，当只有一个类型为 sometype 的输出参数时声明为 SETOF sometype，以便创建一个带有输出参数的设置返回函数。

下面是一个使用 RETURN NEXT 的函数示例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

下面是一个使用 RETURN QUERY 的函数示例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 语句是 IF 语句中最简单的形式。如果条件为 true，则 THEN 和 END IF 之间的语句会被执行。否则，将跳过这些语句。

示例

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 语句在 IF-THEN 中添加内容，让你可以指定当条件不为 true 时应该执行的一系列备用语句。（请注意这包括条件评估为 NULL 的情况。）

示例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有时候不仅仅有两个选择。IF-THEN-ELSIF 提供了一种依次检查多个备选条件的便捷方法。IF 条件会被先后测试，直到找到第一个为 true。然后，关联语句将会被执行，之后控制权将转到 END IF 后的下一个语句。（后面的任何 IF 条件都不会被测试。）如果所有 IF 条件都不为 true，则会执行 ELSE 代码块（如果存在）。

这是一个示例

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

关键词 ELSIF 也可以拼写为 ELSEIF。

完成相同任务的另一种方法是嵌套 IF-THEN-ELSE 语句，如下面的示例

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

但是，这种方法需要为每个 IF 编写匹配的 END IF，因此在有多个备选条件时，这种方法比使用 ELSIF 更加繁琐。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

简单版本的 CASE 根据运算符的相等性提供条件执行。search-expression 会被（一次）评估并且先后与 WHEN 子句中的每个 expression 进行比较。如果找到匹配，则会执行相应的 statements，然后控制权将转到 END CASE 后的下一个语句。（后面的 WHEN 表达式不会被评估。）如果未找到匹配，则会执行 ELSE statements；但是如果不存在 ELSE，则会引发 CASE_NOT_FOUND 异常。

这是一个简单的示例

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 搜索结果根据布尔表达式的真假提供条件执行。依次对每个 WHEN 从句的 boolean-expression 进行评估，直至找到产生 true 结果的表达式。然后，执行相应的 statements，接着控制权转至 END CASE 之后的下一行语句（不会评估后续 WHEN 表达式）。如果没有找到真结果，将执行 ELSE statements；但如果未找到 ELSE，则会引发 CASE_NOT_FOUND 异常。

这是一个示例

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

这种 CASE 形式与 IF-THEN-ELSIF 完全等效，规则除外：错过 ELSE 从句会导致错误，而不是不执行任何操作。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定义一个无条件循环，在被 EXIT 或 RETURN 语句终止之前无限期重复。使用 label（可选）时，可以在嵌套循环中的 EXIT 和 CONTINUE 语句中指定这些语句引用的循环。

EXIT [ label ] [ WHEN boolean-expression ];

如果没有给定 label，将终止最内层循环，接下来执行 END LOOP 之后的语句。如果给定了 label，它必须是当前循环或某一层外部嵌套循环或块的标签。然后，终止命名循环或块，并使用循环/块相应的 END 之后语句继续执行。

如果指定了 WHEN，只有当 boolean-expression 为真时，才会退出循环。否则，控制权转至 EXIT 之后的语句。

EXIT 可用于所有类型的循环；不限于无条件循环。

和 BEGIN 块一起使用时，EXIT 将控制权传递给该块结束后的下一条语句。注意，必须使用一个标签来实现此目的；没有标签的 EXIT 永远不会与 BEGIN 块匹配。（这是对 PostgreSQL 8.4 版本之前版本的一个更改，这些版本允许没有标签的 EXIT 与 BEGIN 块匹配。）

示例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果没有给出 label，则将开始最内层循环的下一个迭代。也就是说，跳过循环体中保留的所有语句，并且控制权返回到循环控制表达式（如果有）以确定是否需要另一个循环迭代。如果存在 label，则它指定将继续执行的循环的标签。

如果指定了 WHEN，则只有当 boolean-expression 为真，才会开始循环的下一个迭代。否则，控制权将传递给 CONTINUE 之后的语句。

CONTINUE 可与所有类型的循环一起使用；它不限于与无条件循环一起使用。

示例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

WHILE 语句重复一段时间内的一系列语句，只要 boolean-expression 求值为真。每次进入循环体之前都会检查此表达式。

例如

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

此 FOR 形式创建一个循环，它在一系列整数值上进行迭代。变量 name 自动定义为类型 integer 并且仅存在于循环中（该循环内忽略该变量名的任何现有定义）。给出范围下限和上限的两个表达式在进入循环时评估一次。如果未指定 BY 子句，则迭代步长为 1，否则为 BY 子句中指定的值，并且在循环进入时再次评估一次。如果指定了 REVERSE，则在每次迭代之后会减去步长值，而不是相加。

整数 FOR 循环的一些示例

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大于上限（或在 REVERSE 情况下小于），则根本不执行循环体。不会引发错误。

如果一个 label 连接到 FOR 循环，则整数循环变量可以使用限定名称引用，用该 label。

[ <<label>> ]
[ DECLARE
    declarations ]
BEGIN
    statements
EXCEPTION
    WHEN condition [ OR condition ... ] THEN
        handler_statements
    [ WHEN condition [ OR condition ... ] THEN
          handler_statements
      ... ]
END;

WHEN division_by_zero THEN ...
WHEN SQLSTATE '22012' THEN ...

INSERT INTO mytab(firstname, lastname) VALUES('Tom', 'Jones');
BEGIN
    UPDATE mytab SET firstname = 'Joe' WHERE lastname = 'Jones';
    x := x + 1;
    y := x / 0;
EXCEPTION
    WHEN division_by_zero THEN
        RAISE NOTICE 'caught division_by_zero';
        RETURN x;
END;

CREATE TABLE db (a INT PRIMARY KEY, b TEXT);

CREATE FUNCTION merge_db(key INT, data TEXT) RETURNS VOID AS
$$
BEGIN
    LOOP
        -- first try to update the key
        UPDATE db SET b = data WHERE a = key;
        IF found THEN
            RETURN;
        END IF;
        -- not there, so try to insert the key
        -- if someone else inserts the same key concurrently,
        -- we could get a unique-key failure
        BEGIN
            INSERT INTO db(a,b) VALUES (key, data);
            RETURN;
        EXCEPTION WHEN unique_violation THEN
            -- Do nothing, and loop to try the UPDATE again.
        END;
    END LOOP;
END;
$$
LANGUAGE plpgsql;

SELECT merge_db(1, 'david');
SELECT merge_db(1, 'dennis');

异常处理程序经常需要识别发生的特定错误。在PL/pgSQL中，有两种方法可以获取有关当前异常的信息：特殊变量和GET STACKED DIAGNOSTICS 命令。

在异常处理程序内，特殊变量SQLSTATE 包含与引发异常对应的错误代码（请参阅表 A.1以获取可能的错误代码列表）。特殊变量SQLERRM 包含与异常关联的错误消息。这些变量在异常处理程序外部未定义。

在异常处理程序内，还可以使用GET STACKED DIAGNOSTICS 命令检索有关当前异常的信息，其形式为

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每个项目 是标识要分配给指定变量 （应该是接收它的正确数据类型）的状态值的关键字。当前可用的状态项目显示在表 41.2中。

如果异常没有为一个项目设置值，将会返回一个空字符串。

这是一个示例

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;